Swedish stemming algorithm

Links to resources

• Scandinavian language stemmers
• Javascript demo
• The stemmer in Snowball
• Sample Swedish vocabulary
• Its stemmed equivalent
• Swedish stop word list (UTF-8 encoding)

Here is a sample of Swedish vocabulary, with the stemmed forms that will be generated by this algorithm:

The stemming algorithm

The Swedish alphabet includes the following additional letters,

ä   å   ö

The following letters are vowels:

a   e   i   o   u   y   ä   å   ö

R2 is not used: R1 is defined in the same way as in the German stemmer. (See the note on R1 and R2.)

Define a valid s-ending as one of

b   c   d   f   g   h   j   k   l   m   n   o   p   r   t   v   y

Define a valid öst-ending as one of

i   k   l   n   p   r   t   u   v

Do each of steps 1, 2 and 3.

Step 1:

Search for the longest among the following suffixes in R1, and perform the action indicated.

(a) a   arna   erna   heterna   orna   ad   e   ade   ande   arne   are   aste   en   anden   aren   heten   ern   ar   er   heter   or   as   arnas   ernas   ornas   es   ades   andes   ens   arens   hetens   erns   at   andet   het   ast

delete

(b) s

delete if preceded by a valid s-ending

(Of course the letter of the valid s-ending is not necessarily in R1)

Step 2:

Search for one of the following suffixes in R1, and if found delete the last letter.

dd   gd   nn   dt   gt   kt   tt

(For example, friskt → frisk, fröknarnn fröknarn)

Step 3:

Search for the longest among the following suffixes in R1, and perform the action indicated.

lig   ig   els

delete

öst

replace with ös if preceded by a valid öst-ending

fullt

replace with full

(The letter of the valid öst-ending is not necessarily in R1. Prior to Snowball 2.3.0, öst-ending was effectively just l and was required to be in R1.)

The same algorithm in Snowball

routines (
           mark_regions
           main_suffix
           consonant_pair
           other_suffix
)

externals ( stem )

integers ( p1 x )

groupings ( v s_ending ost_ending )

stringescapes {}

/* special characters */

stringdef a"   '{U+00E4}'
stringdef ao   '{U+00E5}'
stringdef o"   '{U+00F6}'

define v 'aeiouy{a"}{ao}{o"}'

define s_ending  'bcdfghjklmnoprtvy'

define ost_ending 'iklnprtuv'

define mark_regions as (

    $p1 = limit
    test ( hop 3 setmark x )
    goto v gopast non-v  setmark p1
    try ( $p1 < x  $p1 = x )
)

backwardmode (

    define main_suffix as (
        setlimit tomark p1 for ([substring])
        among(

            'a' 'arna' 'erna' 'heterna' 'orna' 'ad' 'e' 'ade' 'ande' 'arne'
            'are' 'aste' 'en' 'anden' 'aren' 'heten' 'ern' 'ar' 'er' 'heter'
            'or' 'as' 'arnas' 'ernas' 'ornas' 'es' 'ades' 'andes' 'ens' 'arens'
            'hetens' 'erns' 'at' 'andet' 'het' 'ast'
                (delete)
            's'
                (s_ending delete)
        )
    )

    define consonant_pair as setlimit tomark p1 for (
        among('dd' 'gd' 'nn' 'dt' 'gt' 'kt' 'tt')
        and ([next] delete)
    )

    define other_suffix as (
        setlimit tomark p1 for ([substring])
        among(
            'lig' 'ig' 'els' (delete)
            '{o"}st'         (ost_ending <-'{o"}s')
            'fullt'          (<-'full')
        )
    )
)

define stem as (

    do mark_regions
    backwards (
        do main_suffix
        do consonant_pair
        do other_suffix
    )
)